テキストファイル(UTF-8)の作成

シート上の一定のセル範囲にあるデータを UTF-8(Uni-Code) のテキストデータとして出力するマクロのサンプルです。
ただそれだけです。

' # 参照設定：Microsoft ActiveX Data Objects 2.8 Library

Public Sub Main()
　　Const cFilename As String = "TESTOUT.txt"
　　Const cStartRow As Long = 2
　　Dim EndRow As Long
　　Dim ADOStream As ADODB.Stream
　　Dim shtT As Worksheet
　　Dim i As Long
　　Dim aryItem As Variant
　　Dim OtRec As String
　　Dim FName As String

　　Set shtT = ThisWorkbook.Worksheets("Sheet1")
　　' B列を基準に最終行番号を取得する
　　EndRow = shtT.Cells(shtT.Rows.Count, 2).End(xlUp).Row

　　FName = Application.GetSaveAsFilename(InitialFileName:=ThisWorkbook.Path & "\" & cFilename _
　　　　　　　　　　　　　　　　　　　　, FileFilter:="テキストファイル (*.txt), *.txt" _
　　　　　　　　　　　　　　　　　　　　, Title:="出力ファイルの指定")
　　If FName = CStr(False) Then Exit Sub

　　Set ADOStream = New ADODB.Stream
　　ADOStream.Open
　　ADOStream.Charset = "UTF-8"

　　On Error GoTo Error_Rtn
　　For i = cStartRow To EndRow
　　　　' B列を基準に３列分のデータを取得する
　　　　aryItem = shtT.Cells(i, 2).Resize(, 3).Value
　　　　' ３列分のデータを１レコードにする
　　　　OtRec = aryItem(1, 1) & "," & aryItem(1, 2) & "," & aryItem(1, 3) & vbCrLf
　　　　'Debug.Print OtRec
　　　　ADOStream.WriteText OtRec
　　Next i

　　ADOStream.SaveToFile Filename:=FName _
　　　　　　　　　　　 , Options:=adSaveCreateOverWrite
　　ADOStream.Close

　　MsgBox "出力完了", vbInformation
Exit Sub

Error_Rtn:
　　Debug.Print "Error_Rtn", "i: " & i
　　ADOStream.Close
　　MsgBox "異常終了", vbExclamation
End Sub